|
|
DevelopmentSega Master System / Mark III / Game Gear |
Home - Forums - Games - Scans - Maps - Cheats - Credits |
FM Chip Detection
Notes:
- This code requires memory address
$c000to contain the correct value to write to port $3e to enable the correct slot, RAM and controller inputs. This is ordinarily the case when running on any Master System with a BIOS. - The result is stored in a variable called HasFM. The code could be trivially changed to instead return the value in a register.
- If the FM chip is detected, it is enabled (and the PSG is disabled on some hardware).
- See Audio Control Port for the details of port $f2's functionality.
- This code was taken from Phantasy Star.
FMDetection:
ld a,($c000)
or $04 ; Disable I/O chip
out ($3E),a
ld bc $0700 ; Counter (7 -> b), plus 0 -> c
-: ld a,b
and %00000001 ; Mask to bit 0 only
out ($f2),a ; Output to the audio control port
ld e,a
in a,($f2) ; Read back
and %00000111 ; Mask to bits 0-2 only
cp e ; Check low 3 bits are the same as what was written
jr nz,+
inc c ; c = # of times the test was passed
+: djnz -
ld a,c
cp 7 ; Check test was passed 7 times out of 7
jr z,+
xor a ; If not, result is 0
+: and 1 ; If so, result is 1
out ($f2),a ; Output result to audio control port
ld (HasFM),a ; Store result in HasFM
ld a,($c000)
out ($3e),a ; Turn I/O chip back on
ret
ld a,($c000)
or $04 ; Disable I/O chip
out ($3E),a
ld bc $0700 ; Counter (7 -> b), plus 0 -> c
-: ld a,b
and %00000001 ; Mask to bit 0 only
out ($f2),a ; Output to the audio control port
ld e,a
in a,($f2) ; Read back
and %00000111 ; Mask to bits 0-2 only
cp e ; Check low 3 bits are the same as what was written
jr nz,+
inc c ; c = # of times the test was passed
+: djnz -
ld a,c
cp 7 ; Check test was passed 7 times out of 7
jr z,+
xor a ; If not, result is 0
+: and 1 ; If so, result is 1
out ($f2),a ; Output result to audio control port
ld (HasFM),a ; Store result in HasFM
ld a,($c000)
out ($3e),a ; Turn I/O chip back on
ret
